Elvenbane's Personal Macros

Guides UI and Macro
1

Below are my personal macros I use for each class/spec. The purpose of them is to condense the number of physical keys you need to press by controlling which spell is cast via modifier (alt/shift/ctrl) and adding enhanced targeting capabilities where applicable.

I’ve included the keys I have them bound to but you can use whatever.

Important

Before using these macros make sure you unbind SHIFT 1-6 (Action Page 1-6) keys in your key bindings. If you don’t, pressing any of the shift modified macros will cause you to change action page instead of casting the appropriate spell. As of 9.2.5, you also need to ensure that your Self Cast Key is set to None.

9.2.5 Bug

In 9.2.5 Blizzard introduced a bug where the Self Cast Key interferes with @unit (mouseover, focus, etc.) and @cursor macros. If you want to use modifiers with those types of macros, you need to ensure your Self Cast Key is set to None (even if your Self Cast is set to Auto).

More info on the issue:

Death Knight

Death Knight

` (key to the left of 1) - I use BindPad for this)

Lichborne (alt), Raise Ally (dead), Raise Dead/Gnaw (Unholy)

/cast [mod:alt] Lichborne; [@mouseover,help,dead] [help,dead] Raise Ally; [spec:3,nopet] Raise Dead; [spec:3,@mouseover,harm,nodead] [spec:3] Gnaw

Num * (Naga 6)

Abomination Limb

#showtooltip
/cast Abomination Limb

Blood 1
Rune Tap (shift+alt), Empowered Rune Weapon (shift), Death and Decay (alt), Marrowrend

#showtooltip
/cast [mod:shiftalt,known:194679] Rune Tap; [mod:shift,known:47568] Empower Rune Weapon; [mod:alt,combat,@cursor] [mod:alt] Death and Decay; Marrowrend
/startattack

Frost 1
Glacial Advance (alt), Empowered Rune Weapon (mod), Obliterate


#showtooltip
/cast [mod:alt,known:194913] Glacial Advance; [mod] Empower Rune Weapon; Obliterate
/startattack

Unholy 1
Army of the Dead (shift+alt), Apocalypse (shift), Raise Dead/Dark Transformation (alt), Scourge Strike

#showtooltip
/cast [mod:shiftalt,known:42650] Army of the Dead; [mod:shift,known:275699] Apocalypse; [mod:alt,nopet] Raise Dead; [mod:alt] Dark Transformation; Scourge Strike
/startattack

Blood 2
Tombstone (shift+alt), Dancing Rune Weapon (shift), Death’s Caress (alt), Blood Boil

#showtooltip
/cast [mod:shiftalt,known:219809] Tombstone; [mod:shift] Dancing Rune Weapon; [mod:alt,@mouseover,harm,nodead] [mod:alt] Death's Caress; Blood Boil
/startattack

Frost 2
Frostwyrm’s Fury (alt), Remorseless Winter

#showtooltip
/cast [mod:alt] Frostwyrm's Fury; Remorseless Winter
/startattack

Unholy 2
Summon Gargoyle (shift+alt), Soul Reaper (alt), Unholy Frenzy (mod), Festering Strike

#showtooltip
/cast [mod:shiftalt,known:49206] Summon Gargoyle; [mod:alt,known:343294] Soul Reaper; [mod,known:207289] Unholy Frenzy; Festering Strike
/startattack

Blood 3
Consumption/Blooddrinker (shift), Bonestorm (alt), Heart Strike

#showtooltip
/cast [mod:shift,known:274156] Consumption; [mod:shift,known:206931] Blooddrinker; [mod:alt,known:194844] Bonestorm; Heart Strike
/startattack

Frost 3
Breath of Sindragosa (alt), Chill Streak (mod), Howling Blast

#showtooltip
/cast [mod:alt,known:152279] Breath of Sindragosa; [mod,known:305392] Chill Streak; Howling Blast
/startattack

Unholy 3
Chains of Ice (shift), Unholy Blight (mod), Outbreak

#showtooltip
/cast [mod:shift] Chains of Ice; [mod,known:115989] Unholy Blight; [@mouseover,harm,nodead] [] Outbreak
/startattack

Blood/Frost/Unholy 4
Blood: Gorefiend’s Grasp (shift+alt), Mind Freeze (alt), Death Strike (nomod), Death Coil
Frost: Death Strike (shift+alt), Mind Freeze (alt), Frost Strike
Unholy: Death Strike (shift+alt), Mind Freeze (alt), Epidemic (nomod), Death Coil

#showtooltip
/cast [mod:shiftalt,known:108199,@player] Gorefiend's Grasp; [nomod,spec:1] [mod:shiftalt,nospec:1] Death Strike; [mod:alt] Mind Freeze; [spec:2] Frost Strike; [nomod,known:207317] Epidemic; [@mouseover,harm,nodead] [] Death Coil
/startattack

Blood/Frost/Unholy 5
Blood: Death Grip (mod), Dark Command
Frost/Unholy: Dark Command (mod), Death Grip

#showtooltip
/cast [nomod,spec:1,@mouseover,harm,nodead] [nomod,spec:1] [mod,nospec:1,@mouseover,harm] [mod,nospec:1] Dark Command; [@mouseover,harm,nodead] [] Death Grip
/startattack

Blood/Frost/Unholy Num- (Naga 4)
Blood: Anti-Magic Zone (shift+alt), Icebound Fortitude (shift), Anti-Magic Shell (alt), Vampiric Blood
Frost: Anti-Magic Zone (shift+alt), Icebound Fortitude (shift), Anti-Magic Shell (alt), Pillar of Frost
Unholy: Anti-Magic Zone (shift+alt), Icebound Fortitude (shift), Anti-Magic Shell (alt), Death and Decay

#showtooltip
/cast [mod:shiftalt,known:51052] Anti-Magic Zone; [mod:shift] Icebound Fortitude; [mod:alt] Anti-Magic Shell; [spec:2] Pillar of Frost; [spec:3,@cursor,combat] [spec:3] Death and Decay; Vampiric Blood
Demon Hunter

Demon Hunter

` (key to the left of 1) - General Dispel & Utility Macro (I use BindPad for this)
Spectral Sight (alt), Consume Magic

/cancelaura Spectral Sight
/cast [mod:alt] Spectral Sight; [@mouseover,harm,nodead] [] Consume Magic

Havoc Num- (Naga 4)
DPS Potion (ctrl), Netherwalk (shift), Blur (alt), Metamorphosis

#showtooltip
/cast [mod:ctrl] Potion of Spectral Agility; [mod:shift,talent:4/3] Netherwalk; [mod:alt] Blur; [@cursor,combat] [] Metamorphosis

Vengeance Num- (Naga 4)
DPS Potion (ctrl), Bulk Extraction (shift), Soul Barrier (alt), Metamorphosis

#showtooltip
/cast [mod:ctrl] Potion of Spectral Agility; [mod:shift,talent:7/3] Bulk Extraction; [mod:alt,talent:6/3] Soul Barrier; Metamorphosis

Kyrian Covenant Num* (Naga 6)
Phial of Serenity (mod, combat), Summon Steward (mod), Elysian Decree

#showtooltip
/cast [mod,combat] Phial of Serenity
/cast [mod] Summon Steward; [@cursor,combat] [] Elysian Decree

Havoc/Vengeance 1
Havoc: Darkness (shift+alt), Chaos Nova (shift), Vengeful Retreat (alt), Fel Rush
Vengeance: Sigil of Misery (shift+alt), Fiery Brand (shift), Demon Spikes (alt), Infernal Strike

#showtooltip
/cast [mod:shiftalt,spec:1] Darkness; [mod:shiftalt,combat,@cursor] [mod:shiftalt] Sigil of Misery; [mod:shift] Chaos Nova; [mod:alt] Vengeful Retreat; Fel Rush
/startattack

Havoc 2
Blade Dance (alt), Felblade/Demon’s Bite (nomod:shift), Immolation Aura

#showtooltip
/stopmacro [channeling:Eye Beam]
/cast [mod:alt] Blade Dance; [nomod:shift,talent:1/3,talent:2/3] Felblade; [nomod:shift,notalent:2/3] Demon's Bite; Immolation Aura
/startattack

Vengeance 2
Spirit Bomb (shift), Soul Cleave (alt), Shear

#showtooltip
/cast [mod:shift,talent:3/3] Spirit Bomb; [mod:alt] Soul Cleave; Shear
/startattack

Havoc 3
Fel Barrage (shift+alt), Glaive Tempest (shift), Throw Glaive (alt), Chaos Strike

#showtooltip
/cast [mod:shiftalt,talent:7/3] Fel Barrage; [mod:shift,talent:3/3] Glaive Tempest; [mod:alt,@mouseover,harm,nodead] [mod:alt] Throw Glaive; Chaos Strike
/startattack

Vengeance 3
Sigil of Silence (shift+alt), Fel Devastation (shift), Throw Glaive (alt), Sigil of Flame

#showtooltip
/cast [mod:shiftalt,combat,@cursor] [mod:shiftalt] Sigil of Silence; [mod:shift] Fel Devastation; [mod:alt,@mouseover,harm,nodead] [mod:alt] Throw Glaive; [@cursor] Sigil of Flame
/startattack

Havoc/Vengence 4
Havoc: Felblade (shift, no demon blades), Disrupt (alt), Eye Beam
Vengeance: Fracture (shift), Disrupt (alt), Immolation Aura

#showtooltip
/cast [mod:shift,spec:1,talent:1/3,notalent:2/2] [mod:shift,spec:2,talent:3/3] Felblade; [mod:alt] Disrupt; [spec:2] Immolation Aura; Eye Beam
/startattack

Havoc/Vengeance 5
Havoc: Fel Eruption (nomod), Torment
Vengeance: Sigil of Chains (mod), Torment

#showtooltip
/cast [mod,spec:2,talent:5/3,combat,@cursor] [mod,spec:2,talent:5/3] Sigil of Chains; [nomod,spec:1,talent:6/3] Fel Eruption; [@mouseover,harm,nodead] [] Torment

Utility Macros

Sigil of Chains

#showtooltip
/cast [mod:alt,@player] [@cursor,combat] [] Sigil of Chains

Sigil of Misery

#showtooltip
/cast [mod:alt,@player] [@cursor,combat] [] Sigil of Misery

Sigil of Silence

#showtooltip
/cast [mod:alt,@player] [@cursor,combat] [] Sigil of Silence

Imprison

#showtooltip
/focus [mod:alt,@focus,noharm] [mod:alt,@focus,dead]
/clearfocus [@focus,noharm] [@focus,dead] [mod:shift]
/cast [mod:alt,@focus,exists] [] Imprison
Evoker

` (key to the left of 1) - General Dispel & Utility Macro (I use BindPad for this)
Rescue (shift), Cauterizing Flame (alt), Expunge/Naturalize

#showtooltip
/cast [mod:shift,known:370665,@mouseover,help,nodead] [mod:shift,known:370665] Rescue; [mod:alt,known:374251,@mouseover,help,nodead] [mod:alt,known:374251] Cauterizing Flame; [spec:2,@mouseover,help,nodead] [spec:2] Naturalize; [@mouseover,help,nodead] [] Expunge

Num * (Naga 6) - Secondary Utility Macro (I use BindPad for this)
Sleep Walk (shift+alt), Landslide (alt), Dream Flight (Pres)/Firestorm (Dev)

/cast [mod:shiftalt,known:360806,@mouseover,harm,nodead] [mod:shiftalt,known:360806] Sleep Walk; [mod:alt,known:358385] Landslide; [known:359816,combat,@cursor] [known:359816] Dream Flight; [known:368847,combat,@cursor] [known:368847] Firestorm

Num- (Naga 4)
Rewind/Spatial Paradox (shift+alt), Renewing Blaze (shift), Obsidian Scales (alt), Stasis/Zephyr

#showtooltip
/cast [mod:shiftalt,spec:2] Rewind; [mod:shiftalt,known:406732,@mouseover,help,nodead] [mod:shiftalt,known:406732] Spatial Paradox; [mod:shift,known:374348] Renewing Blaze; [mod:alt] Obsidian Scales; [known:370537] Stasis;[known:374227]Zephyr

Num+ (Naga 5)
Time Spiral (shift+alt), Hover (shift/combat/indoors), Dragonriding Mount (dragonriding), Flying/Ground Mount

#showtooltip
/cast [mod:shiftalt,known:374968] Time Spiral; [mod:shift] [combat,nomounted] [indoors,nomounted] Hover; [nomod,advflyable] Cliffside Wylderdrake; Cindermane Charger
/dismount [mounted]

1
Tip the Scales (shift+alt), Verdant Embrace (shift), Fire Breath (alt), Living Flame

#showtooltip
/cast [mod:shiftalt] Tip the Scales; [mod:shift,@mouseover,help,nodead] [mod:shift] Verdant Embrace; [mod:alt] Fire Breath; [@mouseover,exists,nodead] [] Living Flame

2 Dev
Oppressing Roar (shift+alt), Emerald Blossom (shift), Eternity Surge (alt), Azure Strike

#showtooltip
/cast [mod:shiftalt,known:372048] Oppressing Roar; [mod:shift,@mouseover,help,nodead] [mod:shift] Emerald Blossom; [mod:alt] Eternity Surge; Azure Strike
/startattack [nomod]

2 Pres
Time Dilation (shift+alt), Emerald Blossom (shift), Dream Breath (alt), Temporal Anomaly/Azure Strike

#showtooltip
/cast [mod:shiftalt,known:357170,@mouseover,help,nodead] [mod:shiftalt,known:357170] Time Dilation; [mod:shift,@mouseover,help,nodead] [mod:shift] Emerald Blossom; [mod:alt] Dream Breath; [nomod,known:373861] Temporal Anomaly; Azure Strike

2 Aug
Oppressing Roar (shift+alt), Emerald Blossom (shift), Upheaval (alt), Eruption

#showtooltip
/cast [mod:shiftalt,known:372048] Oppressing Roar; [mod:shift,@mouseover,help,nodead] [mod:shift] Emerald Blossom; [mod:alt,spec:3] Upheaval; Eruption
/cast [noform:1] Black Attunement
/startattack [nomod]

3 Dev/Aug
Unravel (shift+alt), Tail Swipe (shift), Disintegrate/Ebon Might (alt), Pyre/Prescience

#showtooltip
/cast [mod:shiftalt,known:368432] Unravel; [mod:shift] Tail Swipe; [mod:alt,spec:3] Ebon Might; [mod:alt] Disintegrate; [spec:1,@mouseover,harm,nodead] [spec:1] Pyre; [@mouseover,help,nodead] [@focus,help,nodead] [] Prescience

3 Pres
Unravel (shift+alt), Tail Swipe (shift), Disintegrate (alt), Echo

#showtooltip
/cast [mod:shiftalt,known:368432] Unravel; [mod:shift] Tail Swipe; [mod:alt] Disintegrate; [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Echo

4 Dev/Aug
Wing Buffet (shift), Quell (alt), Shattering Star/Blistering Scales

#showtooltip
/cast [mod:shift] Wing Buffet; [mod:alt,known:351338] [spec:1,noknown:370452] Quell; [known:370452,@mouseover,harm,nodead] [known:370452] Shattering Star; [known:360827,@mouseover,help,nodead] [known:360827] Blistering Scales

4 Pres
Dream Flight (shift+alt), Wing Buffet (shift), Quell (alt), Reversion

#showtooltip
/cast [mod:shiftalt,known:359816,@cursor] Dream Flight; [mod:shift] Wing Buffet; [mod:alt,known:351338] Quell; [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Reversion

5
Deep Breath/Breath of Eons (mod), Dragonrage/Spirit Bloom/Time Skip

#showtooltip
/cast [nomod,spec:1] Dragonrage; [nomod,known:404977,noknown:412713] Time Skip; [nomod,spec:2,@mouseover,help,nodead] [nomod,spec:2] Spiritbloom; [@cursor] Deep Breath
Druid

Rebirth (combat), Revive

#showtooltip
/cast [combat] Rebirth; Revive

` (key to the left of 1) - General Dispel & Utility Macro (I use BindPad for this)
Rebirth (combat, @dead), Revive (@dead), Soothe (enemy), Nature’s Cure (resto), Remove Corruption

/cast [@mouseover,help,dead,combat] [help,dead,combat] Rebirth; [@mouseover,help,dead] [help,dead] Revive; [spec:4,@mouseover,help,nodead] Nature's Cure; [@mouseover,help,nodead] Remove Corruption; [@mouseover,harm,nodead] [harm] Soothe; [spec:4] Nature's Cure; Remove Corruption

Num-
Moonkin Form (shift, balance), Incarnation (shift, resto), Cat Form (alt, ctrl while in bear form), Bear Form (ctrl while in cat form)

#showtooltip
/cast [mod:shift,spec:1] Moonkin Form; [mod:shift,spec:4,talent:5/3] Incarnation: Tree of Life; [mod:alt,noform:1/2] [mod:ctrl,form:1] [nomod:ctrl,form:2] Cat Form; Bear Form(Shapeshift)
/cancelform [mod:alt]

Num+
Dash (alt, cat form), Prowl (cat form), Survival Instincts (alt, bear form), Incapacitating Roar (bear form), Travel Form (shift, or flyable nomod, or swimming, or in combat), Mount (Lucid Nightmare)

#showtooltip 
/cast [mod:shiftalt,talent:2/3,@mouseover,exists][mod:shiftalt,talent:2/3]Wild Charge; [mod:alt,form:2]Dash; [nomod,form:2]Prowl; [mod:alt,form:1]Stampeding Roar;[nomod,form:1]Incapacitating Roar;Travel Form(Shapeshift)
/dismount

1 Restoration
Tranquility (shift+alt), Wild Growth (shift), Lifebloom

#showtooltip
/cast [mod:shiftalt] Tranquility; [mod:shift,@mouseover,help,nodead] [mod:shift] Wild Growth; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Lifebloom

2 Restoration
Flourish (shift+alt), Swiftmend (shift), Rejuvenation

#showtooltip
/cast [mod:shiftalt,spec:4,talent:7/3] Flourish; [mod:shift,spec:4,@mouseover,help,nodead] [mod:shift,spec:4] Swiftmend; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Rejuvenation

3 Restoration
Cenarion Ward (shift), Regrowth

#showtooltip
/cast [mod:shift,spec:4,talent:1/3,@mouseover,help,nodead] [mod:shift,spec:4,talent:1/3] Cenarion Ward; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Regrowth

4 Restoration
Overgrowth (shift+alt), Iron Bark (shift), Efflorescence

#showtooltip
/cast [mod:shiftalt,talent:6/3,@mouseover,help,nodead] [mod:shiftalt,talent:6/3] Overgrowth; [mod:shift,@mouseover,help,nodead] [mod:shift] Ironbark; [@cursor,combat] [] Efflorescence

1 Balance
Regrowth (shift+alt), Sunfire (alt), Moonfire

#showtooltip
/cast [mod:shiftalt,spec:1,@mouseover,help,nodead] [mod:shiftalt,spec:1,@player] Regrowth; [mod,@mouseover,harm,nodead] [mod] Sunfire; [@mouseover,harm,nodead] [] Moonfire

2 Balance
Force of Nature/Warrior of Elune (shift), Starfall (alt), Starfire

#showtooltip
/cast [mod:shift,talent:1/3,combat,@cursor] [mod:shift,talent:1/3] Force of Nature; [mod:shift,talent:1/2] Warrior of Elune; [mod:alt,@cursor] Starfall; Starfire

3 Balance
Celestial Alignment (shift), Starsurge (alt), Wrath

#showtooltip
/cast [mod:shift,spec:1] Celestial Alignment; [mod:alt] Starsurge; Wrath

4 Balance, 4 Feral
Balance: Stellar Flare/Fury of Elune/New Moon (nomod), Solar Beam
Feral: Skull Bash (alt), Ferocious Bite

#showtooltip
/cast [nomod,spec:1,talent:6/3,talent:7/1] [mod:shift,spec:1,talent:6/3] Stellar Flare; [nomod,spec:1,talent:7/2] Fury of Elune; [nomod,spec:1,talent:7/3] New Moon; [spec:1] Solar Beam; [mod:alt,spec:2/3] Skull Bash; Ferocious Bite

1 Feral, 1 Guardian
Cat: Regrowth (shift), Thrash (alt), Rake
Bear: Survival Instincts (shift), Maul (alt), Mangle

#showtooltip
/console autoUnshift 0
/cast [mod:shift,spec:3] Survival Instincts; [mod:shift,spec:2,@player] Regrowth; [mod:alt,spec:2,form:2] Thrash; [mod:alt,spec:3] Maul; [form:2] Rake; Mangle
/console autoUnshift 1
/startattack

2 Feral, 2 Guardian
Cat: Renewal (shift+alt), Swipe (alt), Shred
Bear: Renewal (shift+alt), Barkskin (shift), Swipe (alt), Thrash

#showtooltip
/cast [mod:shiftalt,talent:2/2] Renewal; [mod:shift,spec:3] Barkskin; [nospec:2/3,notalent:3/3,form:1] [mod:alt] Swipe; [form:2] Shred; Thrash
/startattack

3 Feral
Savage Roar (shift), Tiger’s Fury (alt), Rip

#showtooltip
/cast [mod:shift,spec:2,talent:6/3] Savage Roar; [mod:alt,spec:2] Tiger's Fury; Rip

3 Guardian
Bristling Fur (shift), Frenzied Regeneration (alt), Ironfur

#showtooltip
/cast [mod:shift,spec:3,talent:1/3] Bristling Fur; [mod:alt,spec:3] [mod:alt,spec:1/2,talent:3/2] [mod:alt,spec:4,talent:3/3] Frenzied Regeneration; [spec:3] [spec:1/2,talent:3/2] [spec:4,talent:3/3] Ironfur; Barkskin

4 Balance, 4 Feral
Balance: Stellar Flare/Fury of Elune/New Moon (nomod), Solar Beam
Feral: Skull Bash (alt), Ferocious Bite

#showtooltip
/cast [nomod,spec:1,talent:6/3,talent:7/1] [mod:shift,spec:1,talent:6/3] Stellar Flare; [nomod,spec:1,talent:7/2] Fury of Elune; [nomod,spec:1,talent:7/3] New Moon; [spec:1] Solar Beam; [mod:alt,spec:2/3] Skull Bash; Ferocious Bite

4 Guardian
Lunar Beam/Pulverize (shift), Skull Bash (alt), Moonfire

#showtooltip
/cast [mod:shift,spec:3,talent:7/2] Lunar Beam; [mod:shift,spec:3,talent:7/3] Pulverize; [mod:alt] Skull Bash; [@mouseover,harm,nodead] [] Moonfire

5 Feral, 5 Guardian
Feral: Feral Frenzy (nomod), Berserk
Guard: Incarnation: Bear (shift), Growl

#showtooltip
/cast [nomod,spec:2,talent:7/3] Feral Frenzy; [spec:2] Berserk; [mod:shift,spec:3,talent:5/3] Incarnation: Guardian of Ursoc; [@mouseover,harm,nodead] [] Growl
/startattack
Hunter

` (key to the left of 1) - I use BindPad for this
Mend/Revive Pet (shift), Misdirection (alt), Tranquilizing Shot

/cqs
/cast [mod:shift,@pet,exists,nodead] Mend Pet; [mod:shift] Revive Pet; [nomod,@mouseover,harm,nodead] [nomod] Tranquilizing Shot; [@focus,help,nodead] [@mouseover,help,nodead] [help] [@pet,exists] [] Misdirection

Num/ (Naga 8) - I use BindPad for this
Binding Shot (shift), Sentinel Owl (alt), Hunter’s Mark

#showtooltip
/cast [mod:shift,known:109248,@cursor,combat] [mod:shift,known:109248] Binding Shot; [mod:alt,known:388045,@cursor,combat] [mod:alt,known:388045] Sentinel Owl; [@mouseover,harm,nodead] [] Hunter's Mark

BM/MM/SV 1
Barrage/Explosive Shot (shift), Carve/Butchery (sv, alt), Multi-Shot (alt), Kill Command/Arcane Shot

#showtooltip
/cast [mod:shift,known:120360] Barrage; [mod:shift,known:212431] Explosive Shot; [mod:alt,known:187708] Carve; [mod:alt,known:212436] Butchery; [mod:alt] Multi-Shot; [spec:1/3] Kill Command; Arcane Shot
/startattack

BM/MM 2
Bloodshed/A Murder of Crows (shift), Kill Shot (alt), Cobra Shot

#showtooltip
/cast [mod:shift,known:321530] Bloodshed; [mod:shift,known:131894] A Murder of Crows; [mod:alt] Kill Shot; Cobra Shot
/cast [nocombat] Hunter's Mark
/startattack

SV 2
Aspect of the Eagle (shift), Steel Trap (shift), Kill Shot (alt), Raptor Strike

#showtooltip
/cast [mod:shiftalt,known:186289] Aspect of the Eagle; [mod:shift,known:162488] Steel Trap; [mod:alt] Kill Shot; Raptor Strike
/cast [nocombat] Hunter's Mark
/startattack

BM/MM 3
Volley/Dire Beast (alt), Barbed Shot/Steady Shot

#showtooltip
/cast [mod:alt,known:260243,@cursor] Volley; [mod:alt,known:120679] Dire Beast; [spec:1] Barbed Shot; Steady Shot
/startattack [nomod,combat]

SV 3
Flanking Strike (alt), Coordinated Assault (mod), Serpent Sting

#showtooltip
/cast [mod:alt,known:269751] Flanking Strike; [mod,known:360952] Coordinated Assault; [known:271788] Serpent Sting
/startattack

BM/MM/SV 4
BM: Bestial Wrath (nomod), Counter Shot
MM: Rapid Fire (nomod), Counter Shot
SV: Harpoon (shift), Wildfire Bomb (nomod), Muzzle

#showtooltip
/cast [mod:shift,known:203415] Fury of the Eagle; [nomod,known:19574] Bestial Wrath; [nomod,known:257044] Rapid Fire; [nomod,known:259495,@cursor] Wildfire Bomb; [spec:3] Muzzle; Counter Shot
/use [combat] 13
/startattack

BM/MM 5
Death Chakram (nomod), Trueshot/Call of the Wild/Harpoon

#showtooltip
/cast [nomod,known:375891] Death Chakram; [spec:2] Trueshot; [mod:shift,known:190925] Harpoon; Call of the Wild

BM/MM/SV Num- (Naga 4)
Survival of the Fittest (shift+alt), Aspect of the Turtle (shift), Aspect of the Cheetah

#showtooltip
/cancelaura [mod:shift] Aspect of the Turtle
/cast [mod:shiftalt,known:264735] Survival of the Fittest; [mod:shift] Aspect of the Turtle; Aspect of the Cheetah

Num+ (Naga 5)
Shift: Disengage
Combat: Feign Death
Default: Mount

#showtooltip
/cast [mod:shift] Disengage; [combat] [indoors] Feign Death; [nomod,advflyable] Cliffside Wylderdrake;  Huntmaster's Loyal Wolfhawk
/dismount [mounted]
Mage

` (key to the left of 1) - Spellsteal Macro (I use BindPad for this)

/cast [@mouseover,help,nodead] Remove Curse; [@mouseover,harm,nodead] [harm] Spellsteal; Remove Curse

Arcane 1
Time Warp (shift+alt), Charged Up/Supernova (shift), Arcane Missiles (alt), Arcane Barrage

#showtooltip
/cast [mod:altshift] Time Warp; [mod:shift,talent:4/2] Charged Up; [mod:shift,talent:4/3] Supernova; [mod:alt] Arcane Missiles; Arcane Barrage

Fire 1
Time Warp (shift+alt), Pyroblast (alt), Fire Blast

#showtooltip
/cast [mod:altshift] Time Warp; [mod:alt] Pyroblast; Fire Blast

Frost 1
Time Warp (shift+alt), Ice Floes (shift), Frozen Orb (alt), Ice Lance

#showtooltip
/cast [mod:altshift] Time Warp; [mod:shift,talent:2/3] Ice Floes; [mod:alt] Frozen Orb; Ice Lance

Arcane/Fire/Frost 2
Arcane: Prismatic Barrier (shift), Presence of Mind (alt), Arcane Blast
Fire: Blazing Barrier (shift), Combustion (alt), Fireball
Frost: Ice Barrier (shift), Icy Veins (alt), Frostbolt

#showtooltip
/cast [mod:shift,spec:2] Blazing Barrier; [mod:shift,spec:3] Ice Barrier; [mod:shift] Prismatic Barrier; [mod:alt,spec:1] Presence of Mind; [mod:alt,spec:2] Combustion; [mod:alt] Icy Veins; [spec:1] Arcane Blast; [spec:2] Fireball; Frostbolt

Arcane 3
Nether Tempest (nomod), Arcane Power

#showtooltip
/cast [nomod,talent:6/3] Nether Tempest; Arcane Power

Fire 3
Living Bomb (alt), Scorch

#showtooltip
/cast [mod:alt,talent:6/3] Living Bomb; Scorch

Frost 3
Ebonbolt (alt), Comet Storm (mod), Flurry

#showtooltip
/cast [mod:alt,talent:4/3] Ebonbolt; [mod,talent:6/3] Comet Storm; Flurry

Arcane 4
Counterspell (alt), Arcane Explosion

#showtooltip
/cast [mod:alt] Counterspell; Arcane Explosion

Fire 4
Meteor (nomod), Counterspell (alt), Dragon’s Breath

#showtooltip
/cast [nomod,talent:7/3] Meteor; [mod:alt] Counterspell; Dragon's Breath

Frost 4
Counterspell (alt), Freeze/Summon Water Elemental (nomod), Cone of Cold

#showtooltip
/cast [mod:alt] Counterspell; [nomod,pet,combat,@cursor] [nomod,pet] Freeze; [nomod,notalent:1/2] Summon Water Elemental; Cone of Cold

Frost 5
Ray of Frost/Glacial Spike (nomod), Frost Nova

#showtooltip
/cast [nomod,talent:7/2] Ray of Frost; [nomod,talent:7/3] Glacial Spike; Frost Nova

Arcane/Fire/Frost Num- (Naga 4)
Arcane: DPS Pot (ctrl), Greater Invisibility (shift), Mirror Image/Rune of Power (alt), Evocation
Fire: DPS Pot (ctrl), Invisibility (shift), Mirror Image/Rune of Power (alt), Flamestrike
Frost: DPS Pot (ctrl), Invisibility (shift), Mirror Image/Rune of Power (alt), Blizzard

#showtooltip
/cast [mod:ctrl] Potion of Prolonged Power; [mod:shift,spec:2/3] Invisibility; [mod:shift] Greater Invisibility; [mod:alt,talent:3/2] Mirror Image; [mod:alt,talent:3/3] Rune of Power; [spec:1] Evocation; [spec:2] Flamestrike;[@cursor]Blizzard

Num+ (Naga 5)
Blink (indoors/combat/shift), Flying Mount (flyable,nomod), Ground Mount

#showtooltip
/cast [indoors,nomounted] [combat] [mod:shift] Blink; [flyable,nomod] Archmage's Prismatic Disc; Running Wild
/dismount [mounted]

Utility Macros

Ice Block

#showtooltip
/cancelaura [mod] Ice Block/cast Ice Block

Polymorph

#showtooltip
/focus [mod:alt,@focus,noharm] [mod:alt,@focus,dead]
/clearfocus [@focus,noharm] [@focus,dead] [mod:shift]
/cast [mod:alt,@focus,exists] [] Polymorph
Monk

Not Yet Updated

` (key to the left of 1) - General Dispel & Utility Macro (I use BindPad for this)
Diffuse Magic (alt), Dampen Harm (shift), Detox (friend), Touch of Karma (enemy)

/cast [mod:alt] Diffuse Magic; [mod:shift] Dampen Harm; [spec:3,@mouseover,harm,nodead] Touch of Karma; [@mouseover,help,nodead] [help] Detox; [spec:3,harm] Touch of Karma

Num / (Naga 8)
Paralysis (shift+alt), Weapons of Order (alt), Bonedust Brew/Jadefire Stomp

#showtooltip
/cast [mod:shiftalt,@mouseover,harm,nodead] [mod:shiftalt] Paralysis; [mod:alt,known:387184] Weapons of Order; [known:386276,@cursor,combat] [known:386276] Bonedust Brew; [known:388193] Jadefire Stomp

BM/WW 1
BM: Crackling Jade Lightning (shift+alt), Rising Sun Kick (alt), Tiger Palm (nomod), Spinning Crane Kick
WW: Crackling Jade Lightning (shift+alt), Strike of the Wind Lord (shift), Rising Sun Kick (alt), Tiger Palm

#showtooltip
/cast [mod:shiftalt] Crackling Jade Lightning; [mod:shift,known:392983] Strike of the Windlord; [mod:alt] Rising Sun Kick; [nomod,noknown:418359] Tiger Palm; Spinning Crane Kick
/startattack

BM/WW 2
BM: Touch of Death (shift+alt), Breath of Fire (alt), Expel Harm (mod), Blackout Kick
WW: Touch of Death (shift+alt), Whirling Dragon Punch (alt), Expel Harm (mod), Blackout Kick

#showtooltip
/use [mod:shiftalt] Touch of Death; [mod:alt,known:152175] Whirling Dragon Punch; [mod:alt,spec:1] Breath of Fire; [mod] Expel Harm; Blackout Kick
/startattack

BM/WW 3
BM: Exploding Keg (shift+alt), Rushing Jade Wind (alt), Purifying Brew (shift), Keg Smash
WW: Rushing Jade Wind (alt), Chi Burst/Chi Wave (mod), Spinning Crane Kick

#showtooltip
/use [mod:shiftalt,known:325153,@cursor] Exploding Keg; [mod:alt,known:116847] Rushing Jade Wind; [mod:shift,spec:1]Purifying Brew; [mod,known:123986]Chi Burst; [mod,known:115098]Chi Wave; [spec:1]Keg Smash; Spinning Crane Kick
/startattack

BM/WW 4
BM: Ring of Peace (shift+alt), Leg Sweep (shift), Spear Hand Strike (alt), Celestial Brew
WW: Ring of Peace (shift+alt), Leg Sweep (shift), Spear Hand Strike (alt), Fists of Fury

#showtooltip
/cast [mod:shiftalt] Ring of Peace; [mod:shift] Leg Sweep; [mod:alt,@focus,harm,nodead] [mod:alt,known:116705] Spear Hand Strike; [spec:1] Celestial Brew; Fists of Fury
/startattack

BM/WW 5
BM: Provoke
WW: Flying Serpent Kick (nomod), Provoke

#showtooltip
/cast [spec:3,nomod] Flying Serpent Kick; [@mouseover,harm,nodead] [] Provoke

BM Num- (Naga 4)
Summon White Tiger Statue (shift), Fortifying Brew (alt), Racial (mod), Invoke Niuzao, the Black Ox

#showtooltip
/cast [mod:shift,@cursor,combat] [mod:shift] Summon White Tiger Statue; [mod:alt] Fortifying Brew; [mod] RACIAL; Invoke Niuzao, the Black Ox

WW Num- (Naga 4)
DPS Pot (ctrl), Racial (shift+alt), Summon White Tiger Statue (shift), Invoke Xuen, the White Tiger (alt), Serenity/Storm, Earth, and Fire

#showtooltip
/cast [mod:ctrl] DPS POT; [mod:shiftalt] RACIAL; [mod:shift,@cursor] Summon White Tiger Statue; [mod:alt] Invoke Xuen, the White Tiger; [known:152173] Serenity; Storm, Earth, and Fire

MW 1
Sheilun’s Gift (shift+alt), Essence Font (shift), Renewing Mist

#showtooltip
/cast [mod:shiftalt,known:399491] Sheilun's Gift; [mod:shift] Essence Font; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Renewing Mist

MW 2
Life Cocoon (shift), Vivify

#showtooltip
/cast [mod:shift,@mouseover,help,nodead] [mod:shift,help] [mod:shift,@targettarget,help,nodead] [mod:shift] Life Cocoon; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Vivify

MW 3
Zen Pulse (shift+alt), Spinning Crane Kick (shift), Rising Sun Kick (alt), Enveloping Mist

#showtooltip
/cast [mod:shiftalt,known:124081,@mouseover,help,nodead]  [mod:shiftalt,known:124081] Zen Pulse; [mod:shift] Spinning Crane Kick; [mod:alt] Rising Sun Kick; [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Enveloping Mist

MW 4
Ring of Peace (shift+alt), Leg Sweep (shift), Blackout Kick (alt), Tiger Palm

#showtooltip
/cast [mod:shiftalt,known:116844] Ring of Peace; [mod:shift] Leg Sweep; [mod:alt] Blackout Kick; Tiger Palm

MW 5
Summon Jade Serpent Statue (shift)

#showtooltip
/cast [mod:shift,known:115313] Summon Jade Serpent Statue; [mod:shift,known:196725] Refreshing Jade Wind;  [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Soothing Mist

MW Num- (Naga 4)
Mana Tea (shift+alt), Invoke Yu’lon/Chi-Ji (shift), Revival (alt), Thunder Focus Tea

#showtooltip
/cast [mod:shiftalt,known:115869] Mana Tea; [mod:shift,known:322118] Invoke Yu'lon, the Jade Serpent; [mod:shift] Invoke Chi-Ji, the Red Crane; [mod:alt] Revival; Thunder Focus Tea
Paladin

` (key to the left of 1) - General Dispel & Utility Macro (I use BindPad for this)
Blessing of Protection (shift), Blessing of Freedom (alt), Cleanse Toxins (Ret/Prot), Cleanse (Holy)

#showtooltip
/cast [mod:shift,@mouseover,help,nodead] [mod:shift] Blessing of Protection; [mod:alt,@mouseover,help,nodead] [mod:alt] Blessing of Freedom; [spec:2/3,@mouseover,help,nodead] [spec:2/3] Cleanse Toxins; [@mouseover,help,nodead] [] Cleanse

Num - (Naga 4)
Holy: Aura Mastery (shift), Divine Protection (alt), Avenging Wrath
Prot: Guardian of Ancient Kings (shift), Ardent Defender (alt), Avenging Wrath
Ret: Shield of Vengeance (alt), Avenging Wrath

#showtooltip
/cast [mod:shift,spec:1] Aura Mastery; [mod:shift,spec:2] Guardian of Ancient Kings; [mod:alt,spec:1] Divine Protection; [mod:alt,spec:2] Ardent Defender; [mod:alt,spec:3] Shield of Vengeance; Avenging Wrath

1 Ret
Flash of Light (shift+alt), Holy Avenger/Seraphim (shift), Divine Storm (alt), Blade of Justice

#showtooltip
/cast [mod:shiftalt,@mouseover,help,nodead] [mod:shiftalt] Flash of Light; [mod:shift,talent:5/2] Holy Avenger; [mod:shift,talent:5/3] Seraphim; [mod:alt] Divine Storm; Blade of Justice
/startattack [nomod:shiftalt]

1 Prot
Holy Avenger/Seraphim (shift), Word of Glory (alt), Consecration

#showtooltip
/cast [mod:shift,talent:5/2] Holy Avenger; [mod:shift,talent:5/3] Seraphim; [mod:alt,@mouseover,help,nodead] [mod:alt] Word of Glory; Consecration
/startattack

2 Ret, 2 Prot
Ret: Consecration (shift), Templar’s Verdict (alt), Crusader Strike
Prot: Bastion of Light (shift), Shield of the Righteous (alt), Crusader Strike

#showtooltip
/cast [mod:shift,spec:2,talent:2/3] Bastion of Light; [mod:shift,spec:3] Consecration; [mod:alt,spec:3] Templar's Verdict; [mod:alt] Shield of the Righteous; Crusader Strike
/startattack

3 Ret, 3 Prot
Ret: Execution Sentence (shift), Hammer of Wrath (alt), Judgment
Prot: Hammer of Wrath (alt), Judgment

#showtooltip
/cast [mod:shift,spec:3,talent:1/3] Execution Sentence; [mod:alt] Hammer of Wrath; Judgment
/startattack

4 Ret, 4 Prot
Ret: Hammer of Justice (shift), Rebuke (alt), Wake of Ashes
Prot: Hammer of Justice (shift), Rebuke (alt), Avenger’s Shield

#showtooltip
/cast [mod:shift] Hammer of Justice; [mod:alt,spec:2/3] Rebuke; [spec:2,@mouseover,harm,nodead] [spec:2] Avenger's Shield; [spec:3] Wake of Ashes
/startattack

5 Ret, 5 Prot
Hand of Reckoning

#showtooltip
/cast [@mouseover,harm] [] Hand of Reckoning
/startattack

1 Holy
Beacon of Light (shift+alt), Holy Avenger/Seraphim (shift), Holy Shock

#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Beacon of Light; [mod:shift,talent:5/2] Holy Avenger; [mod:shift,talent:5/3] Seraphim; [mod:alt,@player] [@mouseover,exists,nodead] [] Holy Shock

2 Holy
Beacon of Faith (shift + alt), Consecration (shift), Judgment (alt), Crusader Strike

#showtooltip
/cast [mod:shiftalt,talent:7/2,@mouseover,help] [mod:shiftalt,talent:7/2] Beacon of Faith; [mod:shift] Consecration; [mod:alt] Judgment; Crusader Strike
/startattack

3 Holy
Rule of Law (shift+alt), Light of Dawn (shift), Hammer of Wrath (alt), Word of Glory

#showtooltip
/cast [mod:shiftalt,talent:4/3] Rule of Law; [mod:shift] Light of Dawn; [mod:alt] Hammer of Wrath; [@mouseover,exists,nodead] [help] [@targettarget,help,nodead] [] Word of Glory

4 Holy
Holy Light (shift), Flash of Light

#showtooltip
/cast [mod:shift,@mouseover,help,nodead] [mod:shift,help] [mod:shift,@targettarget,help,nodead] [mod:shift] Holy Light; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Flash of Light

5 Holy
Blinding Light (shift+alt), Hammer of Justice (shift), Light of the Martyr

#showtooltip
/cast [mod:shiftalt,talent:3/3] Blinding Light; [mod:shift] Hammer of Justice; [@mouseover,exists,nodead] [] Light of the Martyr
/stopspelltarget

6 Holy
Lay on Hands (shift), Blessing of Sacrifice

#showtooltip
/cast [mod:shift,@mouseover,help,nodead] [mod:shift,@target] Lay on Hands; [@mouseover,help,nodead] [@target] Blessing of Sacrifice
/stopspelltarget
Priest

Shackle Undead (alt,@focus)

#showtooltip
/focus [mod:alt,@focus,noharm] [mod:alt,@focus,dead]
/clearfocus [@focus,noharm] [@focus,dead] [mod:shift]
/cast [mod:alt,@focus,exists] [] Shackle Undead

Mind Control/Dominate Mind (alt,@focus)

#showtooltip
/focus [mod:alt,@focus,noexists] [mod:alt,@focus,dead]
/clearfocus [@focus,noexists] [@focus,dead] [mod:shift]
/cast [mod:alt,@focus,exists] [] Mind Control

` (key to the left of 1) - General Dispel Macro (I use BindPad for this)
Mind Soothe (shift), Mass Dispel (alt), Dispel Magic (harm), Purify Disease (help, shadow), Purify (help)

#showtooltip
/cast [mod:shift] Mind Soothe; [mod:alt] !Mass Dispel; [spec:3,@mouseover,help,nodead] Purify Disease; [@mouseover,help,nodead] Purify; [@mouseover,harm,nodead] [harm] Dispel Magic; [spec:3] Purify Disease; Purify

Num * (Naga 6) (I use BindPad for this)
Dominate Mind (shift+alt), Holy Word: Chastise (ctrl), Empyreal Blaze (shift), Holy Fire (alt), Power Word: Life (help)/Mindgames (harm)

#showtooltip
/cast [mod:shiftalt,known:205364,@mouseover,harm,nodead] [mod:shiftalt,known:205364] Dominate Mind; [mod:ctrl,known:88625] Holy Word: Chastise; [mod:shift,known:372616] Empyreal Blaze; [mod:alt,known:14914,@mouseover,harm,nodead] [mod:alt,known:14914] Holy Fire; [known:373481,@mouseover,help,nodead] Power Word: Life; [known:375901,@mouseover,harm,nodead] [known:375901,harm] Mindgames; [known:373481] Power Word: Life

Shadow

1
Leap of Faith (shift+alt), Halo/Divine Star (shift), Vampiric Touch (alt), Shadow Word: Pain

#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Leap of Faith; [mod:shift,known:120644] Halo; [mod:shift] Divine Star;  [mod:alt,@mouseover,harm,nodead] [mod:alt] Vampiric Touch; [@mouseover,harm,nodead] [] Shadow Word: Pain

2 - Vampiric Embrace (shift+alt), Void Torrent (shift), Shadow Crash (alt), Mind Flay/Mind Spike

#showtooltip
/stopmacro [channeling:Mind Flay: Insanity]
/cast [mod:shiftalt,known:15286] Vampiric Embrace; [mod:shift,known:263165] Void Torrent; [mod:alt,known:205385,@cursor,combat] [mod:alt,known:205385] Shadow Crash; Mind Flay

3 - Power Word: Shield (shift+alt), Devouring Plague (alt), Mind Blast

#showtooltip
/cast [mod:shiftalt,@mouseover,help,nodead] [mod:shiftalt,@player] Power Word: Shield; [mod:alt,@mouseover,harm,nodead] [mod:alt] Devouring Plague; Mind Blast

4 - Psychich Scream (shift+alt), Shadowfiend/Mindbender (shift), Shadow Word: Death (alt), Dark Ascension/Void Eruption

#showtooltip
/cast [mod:shiftalt] Psychic Scream; [mod:shift] Shadowfiend; [mod:alt,@mouseover,harm,nodead] [mod:alt] Shadow Word: Death; [known:391109] Dark Ascension; [@mouseover,harm,nodead] [] Void Eruption

5 - Silence (mod), Fade

#showtooltip
/cast [mod,known:15487] Silence; Fade

Num-
Desperate Prayer (shift+alt), Dispersion (shift), Power Infusion (alt), Shadowform

#showtooltip
/cancelaura [mod:shift] Dispersion
/cast [mod:shiftalt] Desperate Prayer; [mod:shift] Dispersion; [mod:alt,@mouseover,help] [mod:alt,@focus,help] [mod:alt] Power Infusion; !Shadowform
/cast [mod:alt,@player] Power Infusion

Holy

1 - Leap of Faith (shift+alt), Divine Star/Halo (shift), Prayer of Mending

#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Leap of Faith; [mod:shift,known:120517] Halo; [mod:shift] Divine Star; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Prayer of Mending

2 - Symbol of Hope (shift+alt), Guardian Spirit (shift), Flash Heal

#showtooltip
/cast [mod:shiftalt] Symbol of Hope; [mod:shift,@mouseover,help] [mod:shift] Guardian Spirit; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Flash Heal

3 - Smite (shift+alt), Holy Word: Sanctify (shift), Holy Word: Serenity

#showtooltip
/cast [mod:shiftalt] Smite; [mod:shift,combat,@cursor] [mod:shift,@mouseover,help,nodead] [mod:shift] Holy Word: Sanctify; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Holy Word: Serenity

4 - Shadow Word: Pain (shift+alt), Divine Hymn (shift), Circle of Healing

#showtooltip 
/cast [mod:shifalt,@mouseover,harm,nodead] [mod:shiftalt] Shadow Word: Pain; [mod:shift,known:64843] Divine Hymn; [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Circle of Healing

5 - Renew (shift), Heal

#showtooltip
/cast [mod:shift,@mouseover,help,nodead] [mod:shift,help] [mod:shift,@targettarget,help,nodead] [mod:shift] Renew; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Heal

Num- (Number 4 on my Naga) - Power Infusion (shift+alt), Divine Word (shift), Apotheosis/Holy Word: Salvation (alt), Prayer of Healing

#showtooltip
/cast [mod:shiftalt,@mouseover,help]  [mod:shiftalt,@focus,help] [mod:shiftalt] Power Infusion; [mod:shift,known:372760] Divine Word; [mod:alt,known:265202] Holy Word: Salvation; [mod:alt] Apotheosis; [@mouseover,help] [] Prayer of Healing

Discipline

1 - Leap of Faith (shift+alt), Rapture (shift), Penance

#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Leap of Faith; [mod:shift,@mouseover,help,nodead] [mod:shift] Rapture; [mod:alt,@player] [@mouseover,exists,nodead] [] Penance

2 - Evangelism (shift+alt), Pain Suppression (shift), Power Word: Shield

#showtooltip
/cast [mod:shiftalt,known:246287] Evangelism; [mod:shift,@mouseover,help,nodead] [mod:shift] Pain Suppression; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Power Word: Shield

3 - Holy Nova (shift+alt), Mind Blast (alt), Renew/Shadow Word: Pain

#showtooltip
/stopmacro [channeling]
/cast [mod:shiftalt,known:132157] Holy Nova; [mod:alt,@mouseover,harm,nodead] [mod:alt] Mind Blast; [@mouseover,help,nodead] Renew; [@mouseover,harm,nodead] [harm] Shadow Word: Pain; Renew

4 - Psychic Scream (shift+alt), Shadow Word: Death (alt), Shadowfiend (mod), Smite

#showtooltip
/stopmacro [channeling]
/cast [mod:shiftalt] Psychic Scream; [mod:shift,known:32379,@mouseover,harm] [mod:shift,known:32379] Shadow Word: Death; [mod] Shadowfiend; [@mouseover,harm,nodead] [] Smite

5 - Ultimate Penitence (shift), Power Word: Solace (alt), Flash Heal

#showtooltip
/cast [mod:shift,known:421453] Ultimate Penitence; [mod:alt,known:129250,@mouseover,harm] [mod:alt,known:129250] Power Word: Solace; [@mouseover,help] [help] [@targettarget,help,nodead] [] Flash Heal

Num- (Number 4 on my Naga) - Desperate Prayer (shift+alt), Power Word: Barrier/Luminous Barrier (shift), Power Infusion (alt), Power Word: Radiance

#showtooltip
/cast [mod:shiftalt] Desperate Prayer; [mod:shift,known:62618] Power Word: Barrier; [mod:shift] Luminous Barrier; [mod:alt,@mouseover,help,nodead] [mod:alt,@focus,help,nodead] [mod:alt] Power Infusion; [@mouseover,help][] Power Word: Radiance
Rogue

` (key to the left of 1) - General Utility Macro (I use BindPad for this)
Crimson Vial (alt), Grappling Hook (Outlaw), Shadowstep

/cast [mod:alt] Crimson Vial; [spec:2,combat,@cursor] [spec:2] Grappling Hook; [@mouseover,exists,nodead] [] Shadowstep

Assassination/Outlaw/Subtlety Num- (Naga 4)
Assassination: Vanish (mod), Stealth
Outlaw: Adrenaline Rush (alt), Vanish (mod), Stealth
Subtlety: Shadow Blades (ctrl), Shadow Dance (alt), Vanish (mod), Stealth

#showtooltip
/cast [mod:ctrl,spec:3] Shadow Blades; [mod:alt,spec:3] Shadow Dance; [mod:alt,spec:2] Adrenaline Rush; [mod] Vanish; Stealth

Assassination 1
Tricks of the Trade (shift), Blindside (shift), Garrote (alt), Mutilate

#showtooltip
/cast [mod:shiftalt,@focus,help] [mod:shiftalt] Tricks of the Trade; [mod:shift,talent:1/3] Blindside; [mod:alt] Garrote; Sinister Strike
/startattack [nostealth] [nomod:shiftalt]

Assassination 2
Toxic Blade/Exsanguinate (alt), Fan of Knives (mod), Envenom

#showtooltip
/cast [mod:alt,talent:6/2] Toxic Blade; [mod:alt,talent:6/3] Exsanguinate; [mod] Fan of Knives; Envenom
/startattack [nostealth]

Assassination 3
Vendetta (alt), Crimson Vial (mod), Rupture

#showtooltip
/cast [mod:alt] Vendetta; [mod] Crimson Vial; Rupture
/startattack [nostealth,nomod]

Assassination/Outlaw/Subtlety 4
Kick (alt), Sap (stealth), Feint

#showtooltip
/cast [mod:alt] Kick; [stealth] Sap; Feint

Outlaw 1
Tricks of the Trade (shift+alt), Pistol Shot (alt), Ambush (stealth), Sinister Strike

#showtooltip
/cast [mod:shiftalt,@focus,help] [mod:shiftalt] Tricks of the Trade; [mod:alt] Pistol Shot; [stealth] Ambush; Sinister Strike
/startattack [nostealth] [nomod:shift]

Outlaw 2
Marked for Death (alt), Blade Flurry (mod), Run Through

#showtooltip
/cast [mod:alt,talent:3/3] Marked for Death; [mod] Blade Flurry; Dispatch
/startattack [nostealth]

Outlaw 3
Blade Rush/Killing Spree (alt), Crimson Vial (mod), Roll the Bones

#showtooltip
/cast [mod:alt,talent:7/2] Blade Rush; [mod:alt,talent:7/3] Killing Spree; [mod] Crimson Vial; Roll the Bones 
/startattack [nomod:shift]

Subtlety 1
Tricks of the Trade (shift+alt), Symbols of Death (alt), Shadowstrike (stealth/dance), Backstab

#showtooltip
/cast [mod:shiftalt,@focus,help] [mod:shiftalt] Tricks of the Trade; [mod:alt] Symbols of Death; [stance] Shadowstrike; Backstab
/startattack [nostealth] [nomod:shiftalt]

Subtlety 2
Secret Technique/Shuriken Tornado (shift), Shuriken Storm (alt), Eviscerate

#showtooltip
/cast [mod:shift,talent:7/2] Secret Technique; [mod:shift,talent:7/3] Shuriken Tornado; [mod:alt] Shuriken Storm; Eviscerate
/startattack [nostealth]

Subtlety 3
Marked for Death (alt), Crimson Vial (mod), Nightblade

#showtooltip
/cast [mod:alt,talent:3/3] Marked for Death; [mod] Crimson Vial; Nightblade
Shaman

` (key to the left of 1) - General Dispel & Utility Macro (I use BindPad for this)
Purify (resto), Cleanse Spirit (non-resto), Purge

/cast [spec:3,@mouseover,help,nodead] Purify Spirit; [@mouseover,help,nodead] Cleanse Spirit; [@mouseover,harm,nodead] [harm] Purge; [spec:3] Purify Spirit; Cleanse Spirit

Num - (Naga 4)
Ele: Liquid Magma (shift), Stormkeeper/Ascendance (mod), Spiritwalker’s Grace
Enh: Earthen Spike/Ascendance (mod), Feral Spirit
Resto: Ascendance/Wellspring (mod), Spiritwalker’s Grace

#showtooltip
/cast [mod:shift,spec:1,talent:4/3] Liquid Magma Totem; [mod,spec:1,talent:7/2] Stormkeeper; [mod,spec:3,talent:7/2] Wellspring; [mod,spec:3,talent:7/2] Earthen Spike; [mod,talent:7/3] Ascendance; [spec:2] Feral Spirit; Spiritwalker's Grace

Ele 1
Hero (shift+alt), Fire Elemental+Primal (shift), Earth Shock (alt), Flame Shock

#showtooltip
/use [mod:shiftalt]Heroism;[mod:shift,pet:Primal Fire Elemental]Meteor;[mod:shift,pet:Primal Storm Elemental]Eye of the Storm;[mod:shift]Fire Elemental;[mod:alt,@mouseover,harm,nodead][mod:alt]Earth Shock;[@mouseover,harm,nodead][]Flame Shock

Ele 2
Earth Elemental + Primal (shift), Lava Burst (alt), Lightning Bolt

#showtooltip
/cast [mod:shift,pet:Primal Earth Elemental] Harden Skin; [mod:shift] Earth Elemental; [mod:alt] Lava Burst; Lightning Bolt
/petattack

Ele 3
Echoing Shock/Elemental Blast (shift), Earthquake (alt), Chain Lightning

#showtooltip
/cast [mod:shift,talent:2/2] Echoing Shock; [mod:shift,talent:2/3] Elemental Blast; [mod:alt,@cursor,combat] [mod:alt] Earthquake; Chain Lightning
/petattack

Ele 4, Enh 4
Ele: Wind Shear (alt), Icefury (shift), Frost Shock
Enh: Wind Shear (alt), Earthen Spike (shift), Frost Shock

#showtooltip
/cast [mod:alt,@mouseover,harm,nodead] [mod:alt] Wind Shear; [mod:shift,spec:1,talent:6/3] Icefury; [mod:shift,spec:2,talent:7/2] Earthen Spike; Frost Shock
/startattack

Enh 1
Hero (shift+alt), Earth Elemental (shift), Crash Lightning (alt), Flame Shock

#showtooltip
/cast [mod:ctrl] Heroism; [mod:shift] Earth Elemental; [mod:alt] Crash Lightning; [@mouseover,harm,nodead] [] Flame Shock
/startattack

Enh 2
Stormkeeper/Sundering (shift), Lightning Bolt (alt), Stormstrike

#showtooltip
/cast [mod:shift,talent:6/2] Stormkeeper; [mod:shift,talent:6/3] Sundering; [mod:alt] Lightning Bolt; Stormstrike
/startattack

Enh 3
Fearl Lunge/Win Rush Totem (shift), Windfury Totem (alt), Lava Lash

#showtooltip
/cast [mod:shift,talent:5/2] Feral Lunge; [mod:shift,talent:5/3] Wind Rush Totem; [mod:alt] Windfury Totem; Lava Lash
/startattack

Ele 4, Enh 4
Ele: Wind Shear (alt), Elemental Blast (nomod shift), Thunderstorm
Enh: Wind Shear (alt), Earthen Spike (shift), Frost Shock

#showtooltip
/cast [mod:alt,@mouseover,harm,nodead] [mod:alt] Wind Shear; [mod:shift,spec:1,talent:6/3] Icefury; [mod:shift,spec:2,talent:7/2] Earthen Spike; Frost Shock
/startattack

Resto 1
Surge of Earth (shift+alt), Earth Shield (shift), Riptide

#showtooltip
/cast [mod:shiftalt,talent:2/3] Surge of Earth; [mod:shift,@mouseover,help,nodead] [mod:shift,@target] Earth Shield; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Riptide

Resto 2
Mana Tide Totem (shift+alt), Healing Stream Totem (shift), Healing Surge

#showtooltip
/cast [mod:shiftalt] Mana Tide Totem; [mod:shift,spec:3] Healing Stream Totem; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Healing Surge

Resto 3
Downpour (shift+alt), Unleash Life (shift), Chain Heal

#showtooltip
/cast [mod:shiftalt,talent:6/2,@cursor] Downpour; [mod:shift,talent:1/3,@mouseover,help,nodead] [mod:shift,talent:1/3] Unleash Life; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Chain Heal

Resto 4
Spirit Link Totem (mod), Healing Rain

#showtooltip
/cast [mod] Spirit Link Totem; [@cursor,combat] [] Healing Rain

Resto 5
Healing Tide Totem (shift), Healing Wave

#showtooltip
/cast [mod:shift,spec:3] Healing Tide Totem; [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] Healing Wave
Warlock

` (key to the left of 1) - General Pet & Utility Macro (I use BindPad for this)
Dark Pact (alt), Soulstone, Command Demon

/cast [mod:alt,talent:3/3] Dark Pact; [@mouseover,help,dead] [help,dead] Soulstone; [@mouseover,exists,nodead] [] Command Demon

Num- (Naga 4)
Aff: DPS Pot (ctrl), Dark Soul: Misery (alt), Summon Darkglare
Demo: DPS Pot (ctrl), Nether Portal (alt), Summon Demonic Tyrant
Destro: DPS Pot (ctrl), Dark Soul: Instability (alt), Summon Infernal

#showtooltip
/cast [mod:ctrl]Potion of Prolonged Power;[mod:alt,spec:2,talent:7/3]Nether Portal;[mod:alt,spec:3,talent:7/3]Dark Soul: Instability;[mod:alt,talent:7/3]Dark Soul: Misery;[spec:2]Summon Demonic Tyrant;[spec:3]Summon Infernal;Summon Darkglare

Aff 1
Deathbolt (shift), Seed of Corruption (alt), Corruption

#showtooltip
/cast [mod:shift,talent:1/3,@mouseover,harm,nodead] [mod:shift,talent:1/3] Deathbolt; [mod:alt,@mouseover,harm,nodead] [mod:alt] Seed of Corruption; [@mouseover,harm,nodead] [] Corruption
/petattack [@pettarget,noexists]

Demo 1
Power Siphon/Doom (shift), Implosion (alt), Hand of Gul’dan

#showtooltip
/cast [mod:shift,talent:2/2] Power Siphon; [mod:shift,talent:2/3,@mouseover,harm,nodead] [mod:shift,talent:2/3] Doom; [mod:alt] Implosion; [@mouseover,harm,nodead] [] Hand of Gul'dan
/petattack [@pettarget,noexists]

Destro 1
Soul Fire (shift), Conflagrate (alt), Immolate

#showtooltip
/cast [mod:shift,talent:1/3] Soul Fire; [mod:alt] Conflagrate; [@mouseover,harm,nodead] [] Immolate
/petattack [@pettarget,noexists]

Aff 2, Demo 2, Destro 2
Aff: Drain Life (shift), Siphon Life (alt), Shadow Bolt
Demo: Drain Life (shift), Demonbolt (alt), Shadow Bolt
Destro: Drain Life (shift), Chaos Bolt (alt), Incinerate

#showtooltip
/cast [mod:shift] Drain Life; [mod:alt,spec:2,@mouseover,harm,nodead] [mod:alt,spec:2] Demonbolt; [mod:alt,spec:3] Chaos Bolt; [mod:alt,talent:2/3,@mouseover,harm,nodead] [mod:alt,talent:2/3] Siphon Life; Shadow Bolt
/petattack

Aff 3
Haunt (alt), Agony

#showtooltip
/cast [mod:alt,talent:6/2,@mouseover,harm,nodead] [mod:alt,talent:6/2] Haunt; [@mouseover,harm,nodead] [] Agony
/petattack [@pettarget,noexists]

Demo 3
Demonic Strength/Bilescourge Bombers (alt), Grimoire: Felguard (mod), Call Dreadstalkers

#showtooltip
/cast [mod:alt,talent:1/2] Demonic Strength; [mod:alt,talent:1/3] Bilescourge Bombers; [mod,talent:6/3] Grimoire: Felguard; Call Dreadstalkers
/petattack [@pettarget,noexists]

Destro 3
Shadowburn (alt), Channel Demonfire (mod), Havoc

#showtooltip
/cast [mod:alt,talent:2/3,@mouseover,harm,nodead] [mod:alt,talent:2/3] Shadowburn; [mod,talent:7/2] Channel Demonfire;  [@mouseover,harm,nodead] [] Havoc
/petattack [@pettarget,noexists]

Aff 4
Phantom Singularity/Vile Taint (alt), Shadowfury (mod), Unstable Affliction

#showtooltip
/cast [mod:alt,talent:4/2,@mouseover,harm,nodead] [mod:alt,talent:4/2] Phantom Singularity; [mod:alt,talent:4/3,@cursor] Vile Taint; [mod] Shadowfury; [@mouseover,harm,nodead] [] Unstable Affliction
/petattack [@pettarget,noexists]

Demo 4
Soul Strike/Summon Vilefiend (nomod), Shadowfury

#showtooltip
/cast [nomod,talent:4/2] Soul Strike; [nomod,talent:4/3] Summon Vilefiend; Shadowfury
/petattack [@pettarget,noexists]

Destro 4
Cataclysm (alt), Shadowfury (mod), Rain of Fire

#showtooltip
/cast [mod:alt,talent:4/3,@cursor,combat] [mod:alt,talent:4/3] Cataclysm; [mod] Shadowfury; [@cursor,combat] [] Rain of Fire
/petattack [@pettarget,noexists]

Utility

Banish

#showtooltip
/focus [mod:alt,@focus,noharm] [mod:alt,@focus,dead]
/clearfocus [@focus,noharm] [@focus,dead] [mod:shift]
/cast [mod:alt,@focus,exists] [] Banish

Fear

#showtooltip
/focus [mod:alt,@focus,noharm] [mod:alt,@focus,dead]
/clearfocus [@focus,noharm] [@focus,dead] [mod:shift]
/cast [mod:alt,@focus,exists] [] Fear

Enslave Demon

#showtooltip
/focus [mod:alt,@focus,noexists] [mod:alt,@focus,dead] /clearfocus [@focus,noexists] [@focus,dead] [mod:shift]
/cast [mod:alt,@focus,exists] [] Enslave Demon
Warrior

` (key to the left of 1, created via BindPad so it doesn’t take a bar spot)

Spell Reflection (alt), Shattering Throw (shift), Heroic Throw

#showtooltip
/cast [mod:alt] Spell Reflection;[mod:shift,@mouseover,harm,nodead] [mod:shift] Shattering Throw; [@mouseover,harm,nodead] [] Heroic Throw

Num* (Naga 6; created via BindPad so it doesn’t take a bar spot)

Thunderous Roar/Champion’s Spear

#showtooltip
/cast [known:384318] Thunderous Roar;[known:376079,combat,@cursor] [known:376079] Champion's Spear

Arms 1, Fury 1
Arms: Die by the Sword (shift), Execute (alt), Mortal Strike
Fury: Enraged Regen (shif), Execute (alt), Rampage

#showtooltip
/startattack
/use [mod:shift,spec:1] Die by the Sword; [mod:shift] Enraged Regeneration; [mod:alt] Execute; [spec:1] Mortal Strike; Rampage

Arms 2, Fury 2
Arms: Sweeping Strikes (shift), Cleave (alt), Slam
Fury: Thunderous Roar (shift), WW (alt), Bloodthirst

#showtooltip
/startattack
/cast [mod:shift,spec:1] Sweeping Strikes; [mod:shift,known:384318] Thunderous Roar; [mod:alt,known:845] Cleave; [mod:alt] Whirlwind; [spec:1] Slam; Bloodthirst

Arms 3, Fury 3
Arms: Ravager/Bladestorm (shift), Rend/Skullsplitter (alt), Victory Rush (mod), Overpower
Fury: Ravager/Bladestorm (shift), Victory Rush (alt), Raging Blow

#showtooltip
/startattack
/cast [mod:shift,known:228920,@cursor] Ravager; [mod:shift,known:227847] Bladestorm; [mod:alt,known:772] Rend; [mod:alt,known:260643] Skullsplitter; [mod] Victory Rush; [spec:1] Overpower; Raging Blow

Arms 4, Fury 4
Arms: Colossus Smash (nomod), Storm Bolt (nomod alt), Pummel
Fury: Onslaught/Odyn’s Fury (nomod), Storm Bolt (nomod alt), Pummel

#showtooltip
/startattack
/cast [nomod,spec:1] Colossus Smash; [nomod,known:315720] Onslaught; [nomod,known:385059] Odyn's Fury; [nomod:alt,known:107570,@mouseover,harm,nodead] [nomod:alt,known:107570] Storm Bolt; Pummel

Arms 5, Fury 5, Prot 5
Heroic Leap (shift), Intercept (ally), Charge

#showtooltip
/cast [mod:shift,@cursor,combat] [mod:shift] Heroic Leap; [@mouseover,harm,nodead] Charge; [known:3411,@mouseover,help,nodead] [known:3411,help] Intervene; Charge
/startattack [nomod:shift]

Arms/Fury Num- (Naga 4)
Arms: Rallying Cry (shift+alt), Ignore Pain (alt), Avatar
Fury: Rallying Cry (shift+alt), Recklessness (nomod alt), Avatar

#showtooltip
/use [mod:shiftalt] Rallying Cry; [mod:alt,known:190456] Ignore Pain; [nomod:alt,known:1719] Recklessness; Avatar

Prot 1
Shield Charge (shift+alt), Shield Block (shift), Execute (alt), Shield Slam

#showtooltip
/startattack
/cast [mod:shiftalt,known:385952] Shield Charge; [mod:shift] Shield Block; [mod:alt] Execute; Shield Slam

Prot 2
Ravager (shift), Ignore Pain (alt), Thunder Clap

#showtooltip
/startattack
/cast [mod:shift,known:228920,@cursor,combat] [mod:shift,known:228920] Ravager; [mod:alt] Ignore Pain; Thunder Clap

Prot 3
Thunderous Roar (shift), Victory Rush (alt), Revenge

#showtooltip
/startattack
/cast [mod:shift,known:384318] Thunderous Roar; [mod:alt] Victory Rush; Revenge

Prot 4
Devastate (nomod), Shockwave (nomod shift), Stormbolt (nomod alt), Pummel

#showtooltip
/startattack
/cast [nomod,noknown:236279] Devastate; [mod:shift,known:107570] Storm Bolt; [nomod:alt,known:46968] Shockwave; Pummel

Arms 5, Fury 5, Prot 5
Heroic Leap (shift), Intercept (ally), Charge

#showtooltip
/cast [mod:shift,@cursor,combat] [mod:shift] Heroic Leap; [@mouseover,harm,nodead] Charge; [known:3411,@mouseover,help,nodead] [known:3411,help] Intervene; Charge
/startattack [nomod:shift]

Prot 6
Challenging Shout (mod), Taunt

#showtooltip
/cast [mod,spec:3] Challenging Shout; [@mouseover,harm,nodead] [] Taunt
/startattack

Prot Num- (Naga 4)
Prot: Rallying Cry (shift+alt), Last Stand (ctrl), Shield Wall (shift), Berserker Rage (alt), Avatar

#showtooltip
/cast [mod:shiftalt] Rallying Cry; [mod:ctrl] Last Stand; [mod:shift] Shield Wall; [mod:alt,known:18499] Berserker Rage; Avatar

Prot Num+ (Naga 5)

#showtooltip
/cast [spec:3,combat] Demoralizing Shout; [nomod,advflyable] FLYING_MOUNT; GROUND_MOUNT
/dismount [mounted]
20 Likes
4

why you dont use mod control in your macros?

5

I do occasionally it’s just a lower priority modifier for me; slightly harder to hit than the rest with how I rest my hand.

6

master please please give me a hand with a macro
Righteous Defense macro:
i want to make a macro that with mouseover on harm npc launch Righteous Defense on npc.
in other words if a harm npc goes for my partner i can launch Righteous Defense on him (npc harm) not on my partner

7

10 chars…

8

master please read this spell
Righteous Defense
40 yd range

Instant 8 sec cooldown

Requires Paladin

Come to the defense of a friendly target, commanding up to 3 enemies attacking the target to attack the Paladin instead.

i know your macro if i want to cast a interrupt or stun but in this case i have this spell

9

You can remove the [mod:alt,@player]

10

master i come here one more time searching yuor wisdom…
this time i want to create a macro could ress to my mouseover target and the same time send a chat message with the phase i’m ressing you “mouseovertarget”

ty vm x you support master!!!

11

Grab Macro-Talk and it’ll be straightforward.
https://www.curseforge.com/wow/addons/macro-talk

12

not avaible x tbc classics master :frowning:

13

I want to cast death grip and death and decay at my feet. This is what I have soo far but all it does is cast DBD.
#showtooltip
/cast [mod:shift,@mouseover,harm] [mod:shift] Death Grip; [mod:ctrl, @cursor] Death and Decay; [@player] Death and Decay

14

What is DBD?

15

I’m not seeing any obvious problems with the macro, so it’s most likely a keybinding conflict.

What key do you have the macro bound to?

Make sure that you don’t have shift-KEYBIND bound to something else in your keybinds. (Shift-1 to Shift 6 are bound to action bar switching by default, for example.)

Most number pad keys do not play well with shift modifiers on Windows. (As Windows will translate them to things like “Home” and “End” instead of the actual key.)

On macs, you can run into problems with the keypad binds as well. There’s a fix for that here.

1 Like
16

I’m with Udiza, probably a keybind conflict.

Macro can be optimized slightly:

#showtooltip
/cast [mod:shift,@mouseover,harm,nodead] [mod:shift] Death Grip; [mod:ctrl,@cursor] [@player] Death and Decay
17

oops Death and Decay DnD.

18

Thanks for your inputs but it still only cast DnD. I put it on button 12 which is not bound to anything. I even switched it to DND first and death grip last but no death grip.

19

Is that on an MMO mouse? Those are often set to the keypad. If that’s the case and you are on a mac use the expose fix I posted above. For Windows rebind the mouse buttons to something else using your mouse’s software. (F13-F24 are a relatively safe choice to avoid conflicts.)

20

Yeah, what’s the in-game binding?

Numpad with shift sends entirely different hardware events for certain keys.

21

No . It is on the key board (=/+).

22

What icon does the button, on your bars, show when you hold shift?