Macros: Condensing Your Physical Keys

Guides UI and Macro
9
Priest

** Important **
Before using these macros make sure you unbind SHIFT 1-6 (Action Page 1-6) keys in your key bindings. If you don't, pressing any of the shift modified macros will cause you to change action page instead of casting the appropriate spell.

I've included the keys I have them bound to but you can use whatever.

Utility Macros

` (key to the left of 1) - General Dispel Macro (I use BindPad for this)
Mass Dispel (alt), Dispel Magic (harm), Purify Disease (help, shadow), Purify (help)
#showtooltip
/cast [mod:alt] !Mass Dispel; [spec:3,@mouseover,help,nodead] Purify Disease; [@mouseover,help,nodead] Purify; [@mouseover,harm,nodead] [harm] Dispel Magic; [spec:3] Purify Disease; Purify


Shackle (alt,@focus)
#showtooltip
/focus [mod:alt,@focus,noharm] [mod:alt,@focus,dead] 
/clearfocus [@focus,noharm] [@focus,dead] [mod:shift] 
/cast [mod:alt,@focus,exists] [] Shackle Undead


Mind Control (alt,@focus)
#showtooltip
/focus [mod:alt,@focus,noexists] [mod:alt,@focus,dead] 
/clearfocus [@focus,noexists] [@focus,dead] [mod:shift] 
/cast [mod:alt,@focus,exists] [] Mind Control


Shadow

1 - Leap of Faith (shift+alt), Psychic Scream (shift), Vampiric Touch (alt), Shadow Word: Pain
#showtooltip
/cast [mod:shiftalt,@mouseover,help,nodead] [mod:shiftalt] Leap of Faith; [mod:shift] Psychic Scream; [mod:alt,@mouseover,harm,nodead] [mod:alt] Vampiric Touch; [@mouseover,harm,nodead] [] Shadow Word: Pain


2 - Vampiric Embrace (shift+alt), Dark Void (shift), Mind Sear (alt), Mind Flay
#showtooltip
/cast [mod:shiftalt] Vampiric Embrace; [mod:shift,talent:3/3] Dark Void; [mod:alt] Mind Sear; Mind Flay


3 - Power Word: Shield (shift), Shadow Word: Death/Shadow Crash (alt), Mind Blast
#showtooltip
/cast [mod:shift,@player] Power Word: Shield; [mod:alt,talent:5/2,@mouseover,harm,nodead] [mod:alt,talent:5/2] Shadow Word: Death; [mod:alt,talent:5/3,@cursor] Shadow Crash; Mind Blast


4 - Shadowfiend (alt or shift), Void Eruption/Void Bolt
#showtooltip
/cast [mod:alt/shift] Shadowfiend; [@mouseover,harm,nodead] [] Void Eruption


5 - Silence (shift), Fade
#showtooltip
/cast [mod:shift] Silence; Fade


DPS Potion (ctrl), Dispersion (shift), Dark Ascension/Surrender to Madness (alt), Void Torrent (if in SF/VF), Shadowform
#showtooltip
/cancelaura [mod:shift] Dispersion
/cast [mod:ctrl] Potion of Prolonged Power; [mod:shift] Dispersion; [mod:alt,talent:7/2] Dark Ascension; [mod:alt,talent:7/3] Surrender to Madness; [talent:6/3,form] Void Torrent; Shadowform


Holy

1 - Leap of Faith (shift+alt), Divine Star/Halo (shift), Prayer of Mending
#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Leap of Faith; [mod:shift,talent:6/2] Divine Star; [mod:shift,talent:6/3] Halo; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Prayer of Mending


2 - Symbol of Hope (shift+alt), Guardian Spirit (shift), Flash Heal
#showtooltip
/cast [mod:shiftalt] Symbol of Hope; [mod:shift,@mouseover,help] [mod:shift] Guardian Spirit; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Flash Heal


3 - Holy Word: Salvation (shift+alt), Holy Word: Sanctify (shift), Holy Word: Serenity
#showtooltip
/cast [mod:shiftalt,talent:7/3] Holy Word: Salvation; [mod:shift,combat,@cursor] [mod:shift] Holy Word: Sanctify; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Holy Word: Serenity


4 - Binding Heal/Circle of Healing (nomod), Divine Hymn
#showtooltip 
/cast [nomod,talent:5/2,@mouseover,help,nodead] [nomod,talent:5/2] Binding Heal; [nomod,talent:5/3,@mouseover,help,nodead] [nomod,talent:5/3] Circle of Healing; Divine Hymn
/stopspelltarget


5 - Heal (shift), Renew
#showtooltip
/cast [mod:shift,@mouseover,help,nodead] [mod:shift,help] [mod:shift,@targettarget,help,nodead] [mod:shift] Heal; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Renew


Num- (Number 4 on my Naga) - Desperate Prayer (ctrl), Angelic Feather [@player] (shift), Apotheosis/Holy Word: Salvation (alt), Prayer of Healing
#showtooltip
/cast [mod:ctrl] Desperate Prayer; [mod:shift,talent:2/3,@player] Angelic Feather; [mod:alt,talent:7/2] Apotheosis; [mod:alt,talent:7/3] Holy Word: Salvation; [@mouseover,exists] [] Prayer of Healing


Discipline

1 - Leap of Faith (shift+alt), Divine Star/Halo (shift), Penance
#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Leap of Faith; [mod:shift,talent:6/2] Divine Star; [mod:shift,talent:6/3] Halo; [mod:alt,@player] [@mouseover,exists,nodead] [] Penance


2 - Rapture (shift+alt), Pain Suppression (shift), Power Word: Shield
#showtooltip
/cast [mod:shiftalt] Rapture; [mod:shift,@mouseover,help] [mod:shift,help] [mod:shift,@targettarget,help] [mod:shift] Pain Suppression; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Power Word: Shield


3 - Schism (shift), Holy Nova (alt), Shadow Word: Pain
#showtooltip
/cast [mod:shift,talent:1/3,@mouseover,harm,nodead] [mod:shift,talent:1/3] Schism; [mod] Holy Nova; [@mouseover,harm,nodead] [] Shadow Word: Pain


4 - Power Word: Solace (shift), Shadowfiend (mod), Smite
#showtooltip
/cast [mod:shift,talent:3/3,@mouseover,harm,nodead] [mod:shift,talent:3/3] Power Word: Solace; [mod,harm] [mod,@targettarget,harm] [mod] Shadowfiend; [@mouseover,harm,nodead] [] Smite


5 - Shadow Covenant (shift), Power Word: Barrier (mod), Shadow Mend
#showtooltip
/cast [mod:shift,talent:5/3,@mouseover,help] [mod:shift,talent:5/3] Shadow Covenant; [mod] Power Word: Barrier; [@mouseover,help] [help] [@targettarget,help] [] Shadow Mend


Num- (Number 4 on my Naga) - Evangelism (ctrl), Angelic Feather [@player] (shift), Power Word: Radiance
#showtooltip
/cast [mod:ctrl,talent:7/3] Evangelism; [mod:shift,talent:2/3,@player] Angelic Feather; [@mouseover,help] [] Power Word: Radiance