Ramattra Nemesis Form

Is there any way to remove the cooldown for Nemesis Form to make it theres no cooldown at all for Nemesis Form and to remove the given armor hp he gets from it? If someone can show me the rule for that, that would be great! Also to remove the time limit on Nemesis Form

variables
{
	player:
		0: NemesisForm
}

rule("Setup Ramattra")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		"Basic Support"
		Hero Of(Event Player) == Hero(Ramattra);
		"Duplication Support (if used, Basic Support isn't Needed)"
		disabled (Is Duplicating(Event Player) ? Hero Being Duplicated(Event Player) : Hero Of(Event Player)) == Hero(Ramattra);
	}

	actions
	{
		"reduces bonus Healthpool from Nemesis from 225 to 2.25"
		Set Max Health(Event Player, 1);
		"add Fake health"
		Add Health Pool To Player(Event Player, Health, 425 - Max Health Of Type(Event Player, Health), True, False);
		"add Fake Armor"
		Add Health Pool To Player(Event Player, Armor, 100 - Max Health Of Type(Event Player, Armor), True, False);
		"Replace conditon with \"Duplication Support\" condtion for Duplication Support"
		Wait Until(Hero Of(Event Player) != Hero(Ramattra), 99999);
		"remove fake health"
		Remove All Health Pools From Player(Event Player);
		"restore full health"
		Set Max Health(Event Player, 100);
	}
}

rule("Toggle Nemesis")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		"Bind to Toggle State (Ability 1 Bugged cant use it)"
		Is Button Held(Event Player, Button(Interact)) == True;
		"Basic Support"
		Hero Of(Event Player) == Hero(Ramattra);
		"Duplication Support (if used, Basic Support isn't Needed)"
		disabled (Is Duplicating(Event Player) ? Hero Being Duplicated(Event Player) : Hero Of(Event Player)) == Hero(Ramattra);
	}

	actions
	{
		"Toggle State"
		Event Player.NemesisForm = !Event Player.NemesisForm;
		"if toggling off then also end ability"
		Abort If(Event Player.NemesisForm);
		Cancel Primary Action(Event Player);
	}
}

rule("Force Nemesis")
{
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions
	{
		"check current nemesis State"
		Event Player.NemesisForm == True;
		"Checks if Nemesis Form Active"
		Is Using Ability 1(Event Player) != True;
		"Basic Support"
		Hero Of(Event Player) == Hero(Ramattra);
		"Duplication Support (if used, Basic Support isn't Needed)"
		disabled (Is Duplicating(Event Player) ? Hero Being Duplicated(Event Player) : Hero Of(Event Player)) == Hero(Ramattra);
	}

	actions
	{
		"cancel ending animation (dont think this works)"
		Cancel Primary Action(Event Player);
		"restart ability"
		Press Button(Event Player, Button(Ability 1));
		"anti-crash for infinite loops (if it trys restarting ability while unable to start ability)"
		Wait(0.100, Ignore Condition);
		"loop in case unable to start ability when it trys to restart the ability"
		Loop If Condition Is True;
	}
}

this is the best i could do, workshop cant control ability duration so the best i could do for infinite time was automatically restarting the ability however due to a bug in the workshop (ability 1 button is considered pressed as long as the ability is active), i’ve had to bind the toggle to interact.

the bonus armor isn’t temporary its a healable healthpool so i cant really remove it, but i’ve reduced it from 225 to 2.25 so its barely noticeable.

as for the cooldown, any ability cooldown can be removed from the game without the use of the workshop, just go to “hero settings > ramattra > nemesis form cooldown” and set it to 0%